Hi There,

I have a client who would like to be able to change a user's username somehow.  He only wants the administrators to have this feature, if possible.

Is it possible in DNN to for a user's username to be changed?  I couldn't figure out a way to do it.

  -Josh

Hi,

This is the sp that we use to do this

 ALTER PROCEDURE dbo.ChangeDNNUserName
@oldName nvarchar(100),
@newName nvarchar(100)
AS
declare @error_var int, @rowcount_var int
declare @newNameCount int
begin transaction
 select @newNameCount = count(*)
  from Users
  where Username = @newName
 if @newNameCount > 0
 begin
  ROLLBACK TRANSACTION
  RAISERROR('Username already exists. @newName=%s', 11, 1, @newName)
  RETURN
 end
 update Users
 set Username = @newName
 where Username = @oldName
 SELECT @error_var = @@ERROR, @rowcount_var = @@ROWCOUNT
 IF @rowcount_var <> 1 OR @error_var <> 0
 BEGIN
  RAISERROR('Could not Update User.Username. @oldName=%s', 11, 1, @oldName)
  ROLLBACK TRANSACTION
  RETURN
 END
 update aspnet_Users
 set
  Username = @newName,
  LoweredUserName = LOWER(@newName)
 where LoweredUserName = LOWER(@oldName)
 SELECT @error_var = @@ERROR, @rowcount_var = @@ROWCOUNT
 IF @rowcount_var <> 1 OR @error_var <> 0
 BEGIN
  RAISERROR('Could not Update aspnet_Users.Username. @oldName=%s', 11, 1, @oldName)
  ROLLBACK TRANSACTION
  RETURN
 END
Commit transaction
RETURN