I have two modules loaded onto a page. I have a Page.IsPostback condition that applies only to Module #1. if a Postback is fired from Module#2 then I do not want the  Page.IsPostback condition to apply. I need to add a ModuleID filter to the condition, but for this to work I need to be able to identify the module that caused the Postback. I cannot work out where I get this info from!

It is normal ASP.Net behavior for all ascx controls on a page to go through their life cycle whenever any control (in any module or skin object, etc.) on the page causes a postback. Generally, it sould be sufficient for your module control to check for Page.IsPostback and handle accordingly. However, I can see a use case when you would need to identify the module which actually caused the postback. Here is some code which returns the ModuleId of the module causing the postback or a -1 if the postback was not caused by a DNN module. I have not tested it extensively but it should get you started:

Public Function GetPostBackModuleId() As Integer
   Dim ctrlId As String
   Dim mid As Integer = -1
   Dim sc As ScriptManager = ScriptManager.GetCurrent(Page)
   If sc IsNot Nothing AndAlso sc.IsInAsyncPostBack Then
        ctrlId = sc.AsyncPostBackSourceElementID
   Else
        ctrlId = Page.Request.Params.Get("__EVENT_TARGET")
        If String.IsNullOrEmpty(ctrlId) Then
             For Each id As String In Page.Request.form
                  Dim ctl As Control = Page.FindControl(id)
                  If ctl IsNot Nothing AndAlso TypeOf ctl Is System.Web.UI.WebControls.Button Then
                       ctrlId = id
                       Exit For
                  End If
             Next
        End If
    End If
    If Not String.IsNullOrEmpty(ctrlId) Then
        Dim m As RegularExpressions.Match
        m = Regex.Match(ctrlId, "\$ctr(\d+)\$")
        If m.Success Then
               mid = Convert.ToInt32(m.Groups(1).Value)
        End If
    End If
    Return mid
End Function

---

Bill, WESNet Designs
Team Lead - DotNetNuke Gallery Module Project (Not Actively Being Developed)
Extensions Forge Projects . . .
Current: UserExport, ContentDeJour, ePrayer, DNN NewsTicker, By Invitation
Coming Soon: FRBO-For Rent By Owner

William,
in case anyone needs this, I just tested it on DNN 5.6: I had only to correct one line in this function:

ctrlId = Page.Request.Params.Get("__EVENT_TARGET")

to become

ctrlId = Page.Request.Params.Get("__EVENTTARGET")

Maybe this is related with the asp.net version in use? Anyway the function works with this modification.
Thank you for sharing!

al.