Private Shared Sub AddToScheduleInProgress(ByVal objScheduleHistoryItem As ScheduleHistoryItem)
                If Not ScheduleInProgressContains(objScheduleHistoryItem) Then
                    Try
                        objInProgressReadWriteLock.AcquireWriterLock(WriteTimeout)
                        Try
                            If Not ScheduleInProgressContains(objScheduleHistoryItem) Then
                                ' It is safe for this thread to read or write
                                ' from the shared resource.
                                ScheduleInProgress.Add(objScheduleHistoryItem, objScheduleHistoryItem.ScheduleID.ToString)
                                Interlocked.Increment(Writes)
                            End If
                        Finally
                            ' Ensure that the lock is released.
                            objInProgressReadWriteLock.ReleaseWriterLock()
                        End Try
                    Catch ex As ApplicationException
                        ' The writer lock request timed out.
                        Interlocked.Increment(WriterTimeouts)
                        LogException(ex)
                    End Try
                End If
            End Sub


 
            Private Shared Function ScheduleInProgressContains(ByVal objScheduleHistoryItem As ScheduleHistoryItem) As Boolean
                Dim i As Integer


                For i = 1 To GetScheduleInProgressCount()
                    Dim objScheduleHistoryItem2 As ScheduleHistoryItem = CType(ScheduleInProgress.Item(i), ScheduleHistoryItem)
                    If objScheduleHistoryItem2.ScheduleID = objScheduleHistoryItem.ScheduleID Then
                        Return True
                    End If
                Next
                Return False
            End Function
 
 
 '''''''''''''''''''''''''''''''''''''''''''''''''''
            'This is a multi-thread safe method that returns
            'the number of items in the collection of 
            'schedule items in progress.  It first obtains a
            'read lock on the ScheduleProgress object.
            '''''''''''''''''''''''''''''''''''''''''''''''''''
            Public Shared Function GetScheduleInProgressCount() As Integer
                Dim intCount As Integer
                Try
                    objInProgressReadWriteLock.AcquireReaderLock(ReadTimeout)
                    Try
                        ' It is safe for this thread to read from
                        ' the shared resource.
                        intCount = ScheduleInProgress.Count
                        Interlocked.Increment(Reads)
                    Finally
                        ' Ensure that the lock is released.
                        objInProgressReadWriteLock.ReleaseReaderLock()
                    End Try
                Catch ex As ApplicationException
                    ' The reader lock request timed out.
                    Interlocked.Increment(ReaderTimeouts)
                End Try
                Return intCount
            End Function

The looping construct in ScheduleInProgressContains() code is not thread safe. The number of schedules in progress may change between the call to GetScheduleInProgressCount() and the ScheduleInProgress.Item(i). The index may become invalid before the code reaches the reference to the Item() collection. The ScheduleInProgressContains() method should acquire a read lock on the collection. It's a bug.

http://support.dotnetnuke.com/issue/V...