Here's some code from my ePrayer module which fills a drop-down list of user's in roles granted the custom "Moderate" permission. It was written against DNN 5.4.4 but should still work in DNN 6. The pattern of first getting all roles that have been granted "Moderate" permission then getting all users in those roles is the one you'll want to use. In this case the method goes one step further by filtering out those users who have already been approved as moderators and displayed in a GridView (gvModerators) on the same page.

Private Sub FillAvailableModeratorsDDL()
            Dim arrAvailable As New ArrayList
            Dim mpc As New DotNetNuke.Security.Permissions.ModulePermissionController
            Dim rc As New DotNetNuke.Security.Roles.RoleController
            Dim mp As DotNetNuke.Security.Permissions.ModulePermissionInfo
            For Each mp In DotNetNuke.Security.Permissions.ModulePermissionController.GetModulePermissions(ModuleId, TabId)
                If mp.PermissionCode = "WESNet_EPRAYER" And mp.PermissionKey = "MODERATE" Then
                    Dim RoleName As String = mp.RoleName
                    If IsDBNull(mp.RoleName) Then
                        'If mp.RoleName is null then must be individual permission so
                        Dim li As New ListItem(mp.Username, mp.UserID.ToString)
                        If Not arrAvailable.Contains(li) Then arrAvailable.Add(li)
                    Else
                        For Each ui As Entities.Users.UserInfo In rc.GetUsersByRoleName(PortalId, RoleName)
                            Dim li As New ListItem(ui.DisplayName, ui.UserID.ToString)
                            If Not arrAvailable.Contains(li) Then arrAvailable.Add(li)
                        Next
                    End If

                End If
            Next
            Dim i As Integer = arrAvailable.Count - 1
            If gvModerators.DataKeys.Count > 0 Then
                Do While i >= 0
                    Dim li As ListItem = CType(arrAvailable.Item(i), ListItem)
                    Dim j As Integer = 0
                    Do While j < gvModerators.DataKeys.Count
                        Dim dk As DataKey = gvModerators.DataKeys(j)
                        If li.Value = dk.Value.ToString Then
                            arrAvailable.Remove(li)
                            Exit Do
                        End If
                        j += 1
                    Loop
                    i -= 1
                Loop
            End If
            With ddlAvailableModerators
                .DataSource = arrAvailable
                .DataBind()
                .Items.Insert(0, New ListItem(Localize("Select_New_Moderator"), "0"))
            End With
            btnAddModerator.Enabled = arrAvailable.Count > 0
        End Sub

---

Bill, WESNet Designs
Team Lead - DotNetNuke Gallery Module Project (Not Actively Being Developed)
Extensions Forge Projects . . .
Current: UserExport, ContentDeJour, ePrayer, DNN NewsTicker, By Invitation
Coming Soon: FRBO-For Rent By Owner