Go to http://dev.live.com/virtualearth/. Do you notice how good their xsl stylesheet filters out the description so there's no html formatting?

The same rss feed is at http://blogs.msdn.com/virtualearth/rss.xml with all formatting enabled.

Now how do you turn off HTML formatting in an xsl stylesheet?

Allright, this question comes up a lot, so I'm giving, yet another example of how to do it.  Although, this is not the only way or maybe even the best way, but it IS A way.  In the xsl below, I'm using a template to strip the html, limiting the items displayed to 5, and using inline css styling.  This will work on an RSSv2.0 rss feed, but you may have to tweak it a bit to get exactly the look and feel you want.  So, enjoy...

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" exclude-result-prefixes="xsl"
   xmlns:dc="http://purl.org/dc/elements/1.1/">
<xsl:output method="xml" omit-xml-declaration="yes" indent="yes"/>
<!-- RSSv2.0 XSL stylesheet -->
<!-- Displays only 5 items and description stripped of HTML -->
<!-- The template to strip HTML found here: http://code.techinterviews.com/xslt-to-strip-html/26 -->
<!-- and another example here: http://p2p.wrox.com/topic.asp?TOPIC_ID=56239 -->
<!-- 2008/05/21 By Request -->
<!-- Author: Phil 'iwonder' Guerra -->
<!-- Use with Author Attribution Please -->
<!-- ================================== -->

<xsl:template match="/">
<style media="all" lang="en" type="text/css">
.rssChannelTitle
{
 font-family:  Tahoma;
   font-size:  10pt;
 font-weight:  bold;
  text-align:  Left;
}
.rssChannelDescription
{
 font-family: Times;
   font-size: 11pt;
 font-weight: Bold;
  text-align: Left;
}
.rssItemTitle
{
 font-family:  Verdana;
   font-size:  10pt;
   font-weight: BOLD;
 font-color: #00000;
}
.rssItemDescription
{
 font-family:  Verdana;
   font-size:  10pt;
   font-weight:  Normal;
 font-color: red;
}
.rssItemPubDate
{
 font-family:  Times;
   font-size:  8pt;
   font-weight:  Normal;
 font-color: #000000;
}
</style>

 <div>
  <xsl:apply-templates select="rss/channel"/>
  </div>
</xsl:template>

<xsl:template match="rss/channel">
<xsl:variable name="link" select="link"/>
  <xsl:variable name="description" select="description"/>
  <xsl:variable name="image" select="image/url"/>
  <xsl:variable name="idesc" select="image/description"/>
  <xsl:variable name="ilink" select="image/link"/>
  <xsl:variable name="iwide" select="image/width"/>
  <xsl:variable name="ihigh" select="image/height"/>

<div class="rssChannel">
 <xsl:if test="$image">
    <a href="{$ilink}" title="{$idesc}"><xsl:value-of select="ilink" /></a>
    <img src="{$image}" height="{$ihigh}" width="{$iwide}" style="float: left; margin: 2px; border: 0px;"/>
 </xsl:if>
 </div>
 <div class="rssChannelTitle"> 
 <a href="{$link}">
 <xsl:call-template name="strip_HTML">
    <xsl:with-param name="value" select="title" />
</xsl:call-template>
 </a><br/></div>
 

<div class="rssChannelDescription">
<xsl:call-template name="strip_HTML">
    <xsl:with-param name="value" select="description" />
</xsl:call-template></div>
<div class="rssChannelsubHead">
 <xsl:value-of select="webMaster"/><br/>
 <xsl:value-of select="copyright"/><br/>
 <xsl:value-of select="lastBuildDate"/>
 <hr/>
</div>
<xsl:apply-templates select="item"/>

</xsl:template>

<xsl:template match="item">
<xsl:if test="position() &lt; 6"> <!-- limit the display to 5 items -->

  <xsl:variable name="item_link" select="link"/>
  <xsl:variable name="item_title" select="description"/>
  <div class="rssItemTitle">
    <a href="{$item_link}" title="{$item_title}"><xsl:value-of select="title" disable-output-escaping="yes"/></a>
</div>
<div class="rssItemPubDate">
 (<xsl:value-of select="pubDate"/>)
</div>

<div class="rssItemDescription">
<xsl:call-template name="strip_HTML">
    <xsl:with-param name="value" select="description" />
</xsl:call-template>
</div>
<hr/>
</xsl:if> <!-- end of If statement block for limiting number of items -->
</xsl:template>

<xsl:template name="strip_HTML">
<xsl:param name="value"/>
<xsl:choose>
 <xsl:when test="contains($value,'&lt;')">
  <xsl:value-of select="substring-before($value,'&lt;')" disable-output-escaping="yes"/>
  <xsl:choose>
   <xsl:when test="contains(substring-after($value,'&lt;'),'&gt;')">
    <xsl:call-template name="strip_HTML">
    <xsl:with-param name="value"><xsl:value-of select="substring-after($value,'&gt;')"/></xsl:with-param>
    </xsl:call-template>
   </xsl:when>
  <xsl:otherwise>
  </xsl:otherwise>
  </xsl:choose>
 </xsl:when>
<xsl:otherwise>
 <xsl:value-of select="$value" disable-output-escaping="yes"/>
</xsl:otherwise>
</xsl:choose>

</xsl:template>

</xsl:stylesheet>

Cheers ;-)