Hi There.

This is such a stab in the dark, but I really have come royally unstuck on this one - I have spent over 6 hours going over both DNNCreative's XSL Tutorial and your (and IWonder's) numerous posts on DotNetNuke Forums.

Could really do with anyone's help.

I have set up an RSS News module on my site, linked to http://www.dispatch.co.za/rss/Daily%20Dispatch_News.xml

This module sits in a 200px Wide Container.  I've tried numerous times, but failed miserably (I'm new to XML and XSL to style how this feed displays.  I've obviously used all the templates provided on DNNCreative, but am battling to get it right with this particular feed.

I'd like to display the feed as follows:

• Only display the first 5 entries
• Display Title
• Do not display the image
• Display concatonated description (say 120 characters)
• Display Publish Date

It seems as though the original feed has an image as part of the description, and thus the image always displays, regardless of how I set it.
I've seen a number of posts with similar problems, but none that I could decipher successfully to sort out my problem.  Again, any help - or at least a point in the right post's direction.

Regards Jon

Shebang Websites - A product of Mogridge Design
Hey, we're partnered with UntangleMyWeb.com

Allright, here is one solution that takes care of your needs.  The keys to limiting the number of items displayed  is simple coding.  Displaying only the text of the descriptions is a little trickier, and relies heavily on how a feed is delivered by the new source provider, which is always subject to change.  Here in this example, a namespace is used to allow use of the attribute 'content:encoded' which contains mostly text and html, but that may not always be the case. 

At any rate here's the xsl I used on my text dnn v04.05.05 site.  I placed the rss module in the content portion of a page.

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" exclude-result-prefixes="xsl"
   xmlns:content="http://purl.org/rss/1.0/modules/content/"
   xmlns:dc="http://purl.org/dc/elements/1.1/">
<xsl:output method="xml" omit-xml-declaration="yes" indent="yes"/>
<!-- RSSv2.0 XSL stylesheet -->
<!-- Displays only 5 items and only 120 char of content:encoded text -->
<!-- 2008/05/21 By Request -->
<!-- Author: Phil 'iwonder' Guerra -->
<!-- Use with Author Attribution Please -->
<!-- ================================== -->

<xsl:template match="/">
<style media="all" lang="en" type="text/css">
.rssChannelTitle
{
 font-family:  Tahoma;
   font-size:  13pt;
 font-weight:  bold;
  text-align:  Left;
}
.rssChannelDescription
{
 font-family: Times;
   font-size: 11pt;
 font-weight: Bold;
  text-align: Left;
}
.rssItemTitle
{
 font-family:  Verdana;
   font-size:  10pt;
   font-weight: BOLD;
 font-color: #00000;
}
.rssItemDescription
{
 font-family:  Verdana;
   font-size:  10pt;
   font-weight:  Normal;
 font-color: red;
}
.rssItemPubDate
{
 font-family:  Times;
   font-size:  8pt;
   font-weight:  Normal;
 font-color: #000000;
}
</style>

<div>
  <xsl:apply-templates select="rss/channel"/>
  </div>
</xsl:template>
<xsl:template match="rss/channel">
<xsl:variable name="link" select="link"/>
  <xsl:variable name="description" select="description"/>
  <xsl:variable name="image" select="image/url"/>
  <xsl:variable name="idesc" select="image/description"/>
  <xsl:variable name="ilink" select="image/link"/>
  <xsl:variable name="iwide" select="image/width"/>
  <xsl:variable name="ihigh" select="image/height"/>

<div class="rssChannelTitle">
 <xsl:if test="$image">
    <a href="{$ilink}" title="{$idesc}"><xsl:value-of select="ilink" /></a>
    <img src="{$image}" height="{$ihigh}" width="{$iwide}" style="float: left; margin: 2px; border: 0px;"/>
 </xsl:if> 
 <a href="{$link}"><xsl:value-of select="title" /></a><br/>
 </div>
<div class="rssChannelDescription">
 <xsl:value-of select="substring(description,1,120)" disable-output-escaping="no"/><br/>
</div>
<div class="rssChannelsubHead">
 <xsl:value-of select="webMaster"/><br/>
 <xsl:value-of select="copyright"/><br/>
 <xsl:value-of select="lastBuildDate"/>
 <hr/>
</div>

  <xsl:apply-templates select="item"/>
</xsl:template>
<xsl:template match="item">
<xsl:if test="position() &lt; 6"> <!-- limit the display to 5 items -->
  <xsl:variable name="item_link" select="link"/>
  <div class="rssItemTitle">
    <a href="{$item_link}" ><xsl:value-of select="title" disable-output-escaping="yes"/></a>
</div>
<div class="rssItemPubDate">
 (<xsl:value-of select="pubDate"/>)
</div>
<div class="rssItemDescription">
 <xsl:value-of select="substring(content:encoded,4,120)" disable-output-escaping="yes"/>...<br/>
</div> <hr/>
</xsl:if> <!-- end of If statement block for limiting number of items -->
 </xsl:template>

</xsl:stylesheet>

And the output looks like this:

Dispatch Online - News

All the top News stories

---

Bhisho denies any wrongdoing

(Wed, 21 May 2008 06:40:00 GMT)

TWO reports by the World Health Organisation and national Health Department have given irrefutable proof that the public...

---

East London pledges: No attacks on foreigners here

(Wed, 21 May 2008 06:40:00 GMT)

EAST Londoners have vowed that they will not stand by and allow xenophobic attacks to spill over into their city . The p...

---

Union intervenes to calm EL car plant ‘race crisis’

(Wed, 21 May 2008 06:40:00 GMT)

AT LEAST five employees of Mercedes- Benz South Africa are on suspension for two separate racial incidents. Union offici...

---

Girls get helping hand from ex-gang member

(Wed, 21 May 2008 06:40:00 GMT)

A ONE-TIME bank robber has come to the rescue of two teenage East London girls by paying for them to go overseas to repr...

---

More than one winner in Champions League final

(Wed, 21 May 2008 06:40:00 GMT)

THE advance on Moscow is all but complete, and for Chelsea and Manchester United, that means a chance to win the biggest...

---

In the xsl you'll see lots of ideas of things you can modify to suit, including CSS styles.  Give it a go  and let me know how it works for you.

Cheers! ;-)