Ok, so here's a first pass for you to test.  The xsl appears below with sample output.  It's not pretty, but you can change the included style formatting to suit.  The other problem which I've not addressed is allowing cr/lf html.  What this xsl does is just filter all HTML, so even br's are filtered.  This was just a quick way to show you the direction headed.

<?xml version="1.0" encoding="utf-8"?>
<!-- Blogger Feed From Email with HTML Stripped -->
<!-- Phil 'iwonder' Guerra -->
<!-- 2009-02-16 -->
<xsl:stylesheet version="1.0"
  xmlns:atom="http://www.w3.org/2005/Atom"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:dc="http://purl.org/dc/elements/1.1/">
   <xsl:output method="html"/>
 <xsl:template match="/">
  <style>
   <xsl:comment>
   .syndication-content-area {
   }
   .syndication-title {
    font-size: 1.1em;
    font-weight: bold;
   }
   .syndication-description {
    font-size: .9em;
    margin: 0 0 10px 0;
   }
   .syndication-list {
    font-size: .8em;
    margin:0 0 0 20px;
   }
   .syndication-list-item {
    margin: 0 0 5px 0;
   }
   .syndication-list-item a,
   .syndication-list-item a:link {
    color: blue;
   }
   .syndication-list-item a:active,
   .syndication-list-item a:hover {
    color: red;
   }
   .syndication-list-item a:visited {
    color: black;
    text-decoration: none;
   }
   .syndication-list-item-date {
    font-size: .8em;
   }
   .syndication-list-item-description {
    font-size: .9em;
   }
   </xsl:comment>
  </style>
  <xsl:apply-templates select="/atom:feed"/>
 </xsl:template>
 <xsl:template match="/atom:feed">
  <div class="syndication-content-area">
   <div class="syndication-title">
    <xsl:value-of select="atom:title"/>
   </div>
   <div class="syndication-description">
    <xsl:value-of select="atom:tagline"/>
   </div>
   <ul class="syndication-list">
    <xsl:apply-templates select="atom:entry"/>
   </ul>
  </div>
 </xsl:template>
 <xsl:template match="atom:entry">
    <li class="syndication-list-item">
        <a href="{atom:link/@href}">
            <xsl:value-of select="atom:title"/>
        </a>
        <div class="syndication-content-area ">
            <xsl:call-template name="strip_HTML">
                <xsl:with-param name="value" select="atom:content" />
            </xsl:call-template>
        </div>
   </li>
</xsl:template>
 
<xsl:template name="strip_HTML">
<xsl:param name="value"/>
<xsl:choose>
<xsl:when test="contains($value,'&lt;')">
<xsl:value-of select="substring-before($value,'&lt;')" disable-output-escaping="yes"/>
<xsl:choose>
<xsl:when test="contains(substring-after($value,'&lt;'),'&gt;')">
<xsl:call-template name="strip_HTML">
<xsl:with-param name="value"><xsl:value-of select="substring-after($value,'&gt;')"/></xsl:with-param>
</xsl:call-template>
</xsl:when>
<xsl:otherwise>
</xsl:otherwise>
</xsl:choose>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="$value" disable-output-escaping="yes"/>
</xsl:otherwise>
</xsl:choose>
</xsl:template>

</xsl:stylesheet>

Sample Output

Oh how I understand that situation.  I work for a director that maintains the view - 'we are not in the software development business'.  Yet, everytime there is an issue that our clinical information system cannot provide, he turns to me and asks - 'can you do anything about this issue?'  I've tried to tell him that 80% of my duties as a system administrator are focused on providing automation to improve system performance, monitoring, and usability.  Of course, he does not acknowledge those facts, and so provides me very little in the way of tools to do my job.  If I had not grabbed hold of DNN and other MS .Net tools at various seminars, and recycle a old workstation, load it with linux, we'ld not have any of the tools that help folks do their jobs around here at the system level.  Thanks for .Net, KSH, and XML/XSL tools.

Glad it could help you.

Cheers!